keycloak-mock/build.gradle.kts at main · TNG/keycloak-mock · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
import org.sonarqube.gradle.SonarExtension

plugins {
    idea
    alias(libs.plugins.axion.release)
    alias(libs.plugins.jib) apply false
    alias(libs.plugins.nmcp) apply false
    alias(libs.plugins.nmcp.aggregation)
    alias(libs.plugins.sonarqube)
}

tasks.wrapper {
    gradleVersion = libs.versions.gradle.get()
    distributionType = Wrapper.DistributionType.ALL
}

scmVersion {
    tag {
        prefix = "v"
        versionSeparator = ""
    }
    branchVersionIncrementer = mapOf(
        "feature/.*" to "incrementMinor",
        "main" to "incrementMinor",
    )
}

group = "com.tngtech.keycloakmock"
version = scmVersion.version

repositories {
    mavenCentral()
    google()
}

configure<SonarExtension> {
    isSkipProject = System.getenv("SONAR_TOKEN")?.trim()?.isEmpty() ?: true
    properties {
        property("sonar.host.url", "https://sonarcloud.io")
        property("sonar.organization", "tng")
        property("sonar.projectKey", "TNG_keycloak-mock")
        property("sonar.cpd.exclusions", "mock-junit/**")
        property("sonar.gradle.skipCompile", "true")
    }
}

nmcpAggregation {
    centralPortal {
        username = findProperty("sonatypeUsername") as String?
        password = findProperty("sonatypePassword") as String?
        publishingType = "AUTOMATIC"
    }
}

dependencies {
    nmcpAggregation(project(":mock"))
    nmcpAggregation(project(":mock-junit"))
    nmcpAggregation(project(":mock-junit5"))
    nmcpAggregation(project(":standalone"))
}

// Run the build-logic tests as part of every subproject build, so the
// tamper-guard script (unit-tested in build-logic) is verified before any
// subproject is built. The root project applies no `base` plugin, so there is
// no aggregate `build` task to hook; attach to each subproject's `build` instead.
subprojects {
    tasks.matching { it.name == "build" }.configureEach {
        dependsOn(gradle.includedBuild("build-logic").task(":test"))
    }
}